We have two equations derived from the Markov model in the paper. The first is that the sum of the state number i (i.e. number of valid pages in a block) times the fraction of blocks in state i gives us the mean number of valid pages in a block, (Subscript[N, p])/α :

eq1 = Sum[k,{i,(Subscript[X, 0]),(Subscript[N, p])}] == (Subscript[N, p])/α

The second is that the state probabilities (or equivalently, fraction of blocks in state i) sum to 1. (ignore the subscript on (Subscript[k, i])- it's to force non-evaluated output).

Sum[(Subscript[f, i]),{i,(Subscript[X, 0]),(Subscript[N, p])}] == Sum[(Subscript[k, i])/i,{i,(Subscript[X, 0]),(Subscript[N, p])}] == 1

The exact solution to that summation is quite ugly, so we approximate it with an integral with continuity correction:

eq2 = Integrate[k/i, {i, (Subscript[X, 0])-1/2,(Subscript[N, p])+1/2}, Assumptions->{k>0,1 < (Subscript[X, 0])<(Subscript[N, p])}] == 1

Now we can get a solution for (Subscript[X, 0]), the lowest-numbered state with non-negligible occupation (see the graph in the paper for details):

soln1 = Solve[eq1, k][[1]]

soln = Solve[eq2 /. soln1, (Subscript[X, 0]),InverseFunctions->True][[1]]

And we can calculate A by observing that blocks have (Subscript[X, 0])-1 valid pages when selected for cleaning:

(Subscript[A, gr])[α_] = FullSimplify[(Subscript[N, p])/((Subscript[N, p])-((Subscript[X, 0])-1)) /. soln]

Here we compare LRU cleaning to Greedy cleaning with (Subscript[N, p])= 16, 64:

(Subscript[A, lru])[α_] = α/(α + ProductLog[(-Exp[-α])*α])

Needs["PlotLegends`"]

Plot[{(Subscript[A, lru])[α],(Subscript[A, gr])[α]/. (Subscript[N, p])->64, (Subscript[A, gr])[α]/.(Subscript[N, p])->16},{α,1.03,1.2},AxesOrigin->{1,0}, PlotStyle-> Thick,PlotLegend->{"LRU", "(Subscript[N, p])=64", "(Subscript[N, p])=16"},TicksStyle->Directive[14]]

With a change of variable we can simplify (Subscript[A, gr])[α] quite a bit:

eq3 = α1 == (1 + 1/(2*(Subscript[N, p])))*α

soln = Solve[eq3,α][[1]]

expr = FullSimplify[(Subscript[A, gr])[α]/.soln]

At which point it starts looking very familiar.

expr2 = expr /. {α_/(α_+ProductLog[-Exp[-α_]*α_]) -> LRU[α]}

LRU[α1]*Apart[expr2/LRU[α1]] == LRU[α1]*eq3[[2]][[2]]

In other words:

(Subscript[A, greedy])[α] == (1+1/(2*(Subscript[N, p])))*(Subscript[A, LRU])[α*(1+1/(2*(Subscript[N, p])))]