TraversalPP = 
  "traversal-pp"
  <returnType> ClassName
  FunctionName
  Args
  Body.
Body 		= "{" Initialize Traversal VisitorMethods "}".
Initialize 	= "initialize" JavaCode.
Traversal 	: Simple | Compound.
Simple = 	[ From ] Constraints To.
Compound = 	Op Traversals.
Op 		: Join.
Join 		= "join".
From 		= "from" <source> ClassName.
To 		= "to" <target> ClassName.
Constraint 	= [<b> Bypassing] <t> Through.
Bypassing 	= "bypassing" Edges.
Through 	= "through" Edges.
Edge 		= "->" <from> ClassName 
		       <l> LabelName <to2> ClassName.
Arg             = <typ> JavaTypeName  <arg> Variable.
VisitorMethod 	: Before | After 
			*common* <hosts> ClassNames JavaCode.
Before          = "before".
After           = "after".


// Terminal-Buffer rule
ClassName 		= <n> Ident.
JavaTypeName            = <name> Ident.
Variable                = <name> Ident.
LabelName               = <name> Ident.
FunctionName            = <name> Ident.
JavaCode                = <code> Text.

// Repetition-Buffer rule
Args            = "(" [ <l> CList(Arg) ] ")".
ClassNames 	= "{" <l> CList(ClassName) "}".
VisitorMethods 	=  <l> NList(VisitorMethod) .
Traversals 	= "(" <l> CList(Traversal) ")".
Edges 		= <l> NList(Edge).
Constraints 	= <l> List(Constraint).

// Repetition classes

CList(S) 	~ S {"," S}.
NList(S) 	~ S {S}.
List(S) 	~ {S}.

Main = .

// Visitors
PrintingVisitor = .
SelectiveVisitor = 
  <doingV> PrintingVisitor
  <soV> SelectorVisitor.
SelectorVisitor = <selected> Boolean.

Test = <i> int.