// ============================================================
// BusRoute.cd : Class dictionary for bus routes.
// Written by Ali Ozmez for the COM3360 project.
// Last update on Tue Nov 28 17:11:12 1995.
// ============================================================

BusRoute =
	"BusRoute:" <name> RouteName
	"total" "route" "length" ":" <totalLength> RouteLen
	"consisting" "of" "bus" "stops" ":" <busStops> List(BusStop)
	"with" "assigned" "busses" ":" <buses> List(Bus).

BusStop	=
	<id> StopId
	"at:" <location> RouteLoc  // clockwise dist. from origin
	"with" "waiting" "list" ":" <waitingList> List(Person).

Bus =
	<id> BusId
	"at:" <position> RouteLoc  // clockwise dist. from origin
	[ "currently" "at" "stop" ":"  <currentStop>  StopId]
	"capacity:" <capacity> BusCapac
	"speed:" <speed> BusSpeed
	"carrying" "passenger(s)" ":" <passengers> List(Person).

Person =
	<id> PersonId
	"destination:" <destination> StopId.   // id of the dest. stop

List(S) ~ "(" { S } ")".

RouteName = <v> String.
RouteLen  = <v> Integer "ft".
RouteLoc  = <v> Integer "ft".
BusCapac  = <v> Integer "passengers".
BusSpeed  = <v> Integer "ft/min".
StopId    = <v> Ident.
BusId     = <v> Ident.
PersonId  = <v> Ident.



---------------------------------------------------------------




Main {
(@
  static public void main(String args[]) throws Exception {
      BusRoute e = BusRoute.parse(System.in);
  }
@)
}

BusRoute {
  traversal allBusRouteBuses() {to Bus;}
}

Bus {
  traversal allBusPersons() {to Person;}
}





---------------------------------------------------------------




// Here is a sample BusRoute object:

BusRoute: "Ruggles / Harvard Square"
total route length : 5000 ft
consisting of bus stops : (
  Stop0 at: 0 ft
	with waiting list : (
	  Person1 destination: Stop1
	  Person2 destination: Stop1
	  Person3 destination: Stop2
	  Person4 destination: Stop2
	)
  Stop1 at: 2000 ft
	with waiting list : (
	  Person10 destination: Stop0
	  Person11 destination: Stop0
	  Person12 destination: Stop0
	  Person13 destination: Stop2
	)
  Stop2 at: 3500 ft
	with waiting list : (
	  Person5 destination: Stop0
	  Person6 destination: Stop1
	  Person7 destination: Stop1
	  Person8 destination: Stop0
	  Person9 destination: Stop1
	  Person10 destination: Stop1
	)
)
with assigned busses : (
  Bus1 	at: 0 ft
	currently at stop : Stop0
	capacity: 5 passengers
	speed: 700 ft/min
	carrying passenger(s) : ()
)