import CPPParser;

//============================================================
// COMAspect Language
//------------------------------------------------------------
COMAspect = COMComp COMGlue.

//============================================================
// COM-Comp Language
//------------------------------------------------------------
COMComp = "COM-Comp" "{" SList(ComponentDescription) "}".
ComponentDescription = <componentname> ComponentNameDescription "from" <classname> ClassDescription "{" <interfaces> InterfaceList "}" ";".
ComponentNameDescription = "component" <name> ComponentName.
ClassDescription = "class" <name> ClassName "in" <filename> FileName.
InterfaceList : List(InterfaceDescription).
InterfaceDescription = "interface" <name> InterfaceName "{" <methodmap> MethodList "}" ";".
MethodList : List(Method).
Method = "method" <imethodname> InterfaceMethodName <methodmap> OptionalMethodMap ";".
OptionalMethodMap : List(MethodMap).
MethodMap = "mapsto" <classmethod> ClassMethodName.

//============================================================
// COM-Glue Language
//------------------------------------------------------------
COMGlue = "COM-Glue" "{" SList(GlueItem) "}".
GlueItem : ComponentGlue | InterfaceGlue.

ComponentGlue = "component" <componentname> ComponentName "{" SList(ComponentGlueItem) "}" ";".
ComponentGlueItem : ClassIDEntry | FriendlyNameEntry | ProgIDEntry | VersionIndProgIDEntry.
ClassIDEntry = "CLSID" "=" ClassID ";".
FriendlyNameEntry = "FriendlyName" "=" <name> FriendlyName ";".
ProgIDEntry = "ProgID" "=" <id> ProgID ";".
VersionIndProgIDEntry = "VersionIndProgID" "=" <id> VersionIndProgID ";".

InterfaceGlue = "interface" <interfacename> InterfaceName "{" SList(InterfaceGlueItem) "}" ";".
InterfaceGlueItem : InterfaceIDEntry.
InterfaceIDEntry = "IID" "=" <id> InterfaceID ";".

ComponentName = <string> String.
ClassName = <string> String.
FileName = <string> String.
InterfaceName = <string> String.
ClassMethodName = <string> String.
InterfaceMethodName = <string> String.

ClassID = Identifier.
FriendlyName = <string> String.
ProgID = <string> String.
VersionIndProgID = <string> String.
InterfaceID = Identifier.
Identifier = String.

//============================================================
// Generic Stuff
//------------------------------------------------------------
List(S) ~ {S}.
SList(S) ~ S { *l S } *l .

Main = .

//============================================================
// Partial C++ Parser
// Does not support external class declarations
// Does not support function pointer arguments
// Only supports built-in types
// Member functions and their args MUST start with capital letters
//------------------------------------------------------------
*noparse*

CPPProgram = TranslationUnit.
TranslationUnit = NPList(ExternalDeclaration).
ExternalDeclaration = Declaration.
Declaration = DeclarationSpecifiers.
DeclarationSpecifiers : UnknownTypeSpecifier | TypeSpecifier | ClassSpecifier *common* <isTypeDef> boolean.
UnknownTypeSpecifier = .
TypeSpecifier = String.
ClassSpecifier = <name> ClassName NPList(MemberDeclaration).
MemberDeclaration : FunctionDefinition.
FunctionDefinition = <name> FunctionName ReturnType NPList(ParameterDeclaration) <scope> Scope.
ParameterDeclaration = TypeSpecifier Declarator.
Declarator = NPList(AnyPointerOperator) <name> String.
FunctionName = String.
ParameterName = String.
AnyPointerOperator : PointerOperator | EPointerOperator.
PointerOperator = String.
EPointerOperator = .
ReturnType = TypeSpecifier.
NPList(S) ~{S}.
*parse*


//============================================================
// Visitors (old school)
//------------------------------------------------------------
*noparse*

COMEmittingVisitor = <currentprog> CPPProgram <aspect> COMAspect.
InterfaceDeclVisitor = <prototype> String <guids> String <classname> String <prog> CPPProgram <aspect> COMAspect.
FuncPrototypeEmittingVisitor = <string> String <method> String <classname> String <currclass> String <funcfound> boolean <writeparen> boolean
                               <paramcount> Integer <mapsto> String.
GUIDEmittingVisitor = <string> String <query> String <ignore> boolean <found> boolean.
RegisteringVisitor = <query> String <clsidname> String <progid> String <vindprogid> String <friendlyname> String
                     <ignore> boolean <found> boolean.
InterfaceListingVisitor = <string> String <ifacecount> Integer.
MethodDeclVisitor = <string> String <classname> String <prog> CPPProgram.
QueryInterfaceEmittingVisitor = <string> String <ifacecount> Integer.
ComponentMethodEmittingVisitor = <string> String <compname> String <classname> String <prog> CPPProgram.
ParamNameListingVisitor = <string> String <paramcount> Integer <method> String <classname> String <ignore> boolean <found> boolean <hasreturnval> boolean <currclassname> String.
*parse*