// LibrarySystem.cd
// Created by Cristina Videira Lopes on 12/20/94.
//
// This file contains the class dictionary for a simple Library System.
//

LibrarySystem = <books> List(Book) <users> List(User)
                [<ops> List(Operation)] .

Book = "book:" Title Author Publisher Year Subject ISBN List(Copy).

Title     = <t> DemString .
Author    = "by" <a> DemString .
Publisher = <p> DemString .
Year      = <y> DemNumber .
Subject   = <s> DemString .
ISBN      = "ISBN" <n> DemNumber .
Copy      = "copy" <n> DemNumber [ <borrower> User ] .

User = "user:" <uid> DemNumber <fname> DemString <lname> DemString
               Address Phones Status.

Address = "address:" <number> DemNumber <street> DemString 
          ["#" <apt> DemNumber] <city> DemString <state> DemString 
          <zip> DemNumber .

Phones = "phones:" [ HomePhone ] [ WorkPhone ] [ Fax ] .

Phone : HomePhone | WorkPhone | Fax
        *common* <area_code> DemNumber "-" <number> DemNumber .

HomePhone   = "home" .
WorkPhone   = "work" .
Fax         = "fax" .

Status = "status:" <quota> DemNumber List(CheckedOut).

CheckedOut  = Book Copy .

Operation : Exit | ShowBooks | SearchBook | ShowUsers | SearchUser |
            CheckBook | Invalid 
            *common* <op_code> DemNumber.

CheckBook : CheckOut | CheckIn *common*.

Exit = "Exit" .
ShowBooks = "Show books" .
SearchBook = "Search book" .
ShowUsers = "Show users" .
SearchUser = "Search user" .
CheckOut = "Check out" .
CheckIn = "Check in" .
Invalid = .

// Generic
List(S) ~ "(" { S } ")" .