import java.io.*;
import java.util.*;

*noparse*
//============================================================
// Registry
//------------------------------------------------------------
Registry =
  <types> TypeList
  <entities> EntityList
  <categories> CategoryList
  . 
TypeList =
  <value> List(DefinedType)
  .
EntityList =
  <value> List(Entity)
  .
CategoryList =
  <value> List(CodeCategory)
  .
//============================================================
// Types
//------------------------------------------------------------
DefinedType :
  ClassType | NonClassType 
  *common*
    <name> TypeName
    <header> HeaderFile
  .
NonClassType =
  .
ClassType :
  SimpleClassType | TemplatedClassType
  .
SimpleClassType =
  .
TemplatedClassType =
  <args> TemplateArgs
  .
TypeName = <value> String .
HeaderFile = <name> String .
TemplateArgs = <value> String .

//============================================================
// Entities
//------------------------------------------------------------
AccessKeyList = 
  List(AccessKey)
  .
Entity =
   <name> EntityName
   <keys> AccessKeyList
   <parents> List(ParentEntity)
   <methods> List(Method)
  .
ParentEntity =
  <value> Entity
  .
EntityName = 
  <value> String
  .
Method =
  <name> MethodName
  [<bodyVersion> MethodBodyVersion]
  <isStatic> boolean
  <isConst> boolean
  <isVirtual> boolean
  <keys> AccessKeyList
  <returnDecl> ReturnDecl
  <args> List(ArgumentDecl)
  .
MethodName =
  <value> String
  .
MethodBodyVersion =
  <value> String
  .
AccessKey =
  <tag> String
  .
TypeDecl : 
  ReturnDecl | ArgumentDecl
  *common*
    <prefix> String
    <suffix> String
    <isRef> boolean           // Indicates type denotes a reference
                              //   rather than a value
    // Note: <type> must preceed <tmplType> (See TypeUseFixup.beh)
    [<type> TypeUse]          // The type itself (absent for intrinsic
                              //   types)
    <tmplType> TypeUseList    // Template arguments
    <arrayDim> ConstantList   // Symbolic array dimensions
  .
TypeUseList =
  <value> List(TypeUse)
  .
ConstantList =
  <value> List(Constant)
  .
ReturnDecl =
  .
ArgumentDecl =
  <name> ArgumentName
  [ <initializer> Constant ]
  .
ArgumentName =
  <value> String
  .
// 'Constant' represents simple constants occuring in type declarations
// Symbolic constants have an associated TypeUse providing access to
// the header file for that constant (which is declared as a
// NonClassType).
Constant :
  SymbolicConstant | LiteralConstant
  *common*
  <image> String
  .
LiteralConstant =
  .
SymbolicConstant =              
  <type> TypeUse
  .
TypeUse =
  <typeName> TypeName
  <needHeader> boolean
  [<type> DefinedType]
  .
//============================================================
// Code Categories
//------------------------------------------------------------
Template : 
  HeaderTemplate | ImplTemplate | MakeTemplate
  *common*
  <file> String
  .
HeaderTemplate = .
ImplTemplate = .
MakeTemplate = .

CodeCategoryType =
  <name> String
  <header> HeaderTemplate
  <impl>   ImplTemplate
  <make>   MakeTemplate
  .
CodeCategory :
  GeneratedCodeCategory | NonGeneratedCodeCategory
  *common*
  <tag> String
  <macroBaseName> String
  <classNamePattern> String
  <headerNamePattern> String
  .
NonGeneratedCodeCategory = 
  .
GeneratedCodeCategory =
  <type> CodeCategoryType
  <keys> AccessKeyList
  .
//============================================================
// Program classes
//------------------------------------------------------------
Main = .

//============================================================
// Utilities
//------------------------------------------------------------
List(E) ~ {E}.