import java.io.*;

*noparse* 
//============================================================
// Type Registry
//------------------------------------------------------------
TypeRegistry =
  List(DefinedType)
  .
DefinedType :
  ClassType | NonClassType 
  *common*
    <name> TypeName
    <header> HeaderFile
  .
NonClassType =
  .
ClassType :
  SimpleClassType | TemplatedClassType
  .
SimpleClassType =
  .
TemplatedClassType =
  <args> TemplateArgs
  .

TypeName = <value> String .
HeaderFile = <name> String .
TemplateArgs = <value> String .

//============================================================
// Entity Registry
//------------------------------------------------------------
EntityRegistry =
  List(Entity)
  .
AccessKeyList = 
  List(AccessKey)
  .
Entity =
   <name> EntityName
   <parents> List(ParentEntity)
   <methods> List(Method)
   <keys> AccessKeyList
  .
ParentEntity =
  <name> EntityName
  [ Entity ]
  .
EntityName = 
  <value> String
  .
Method =
  <name> MethodName
  <bodyVersion> MethodBodyVersion
  <isStatic> boolean
  <isConst> boolean
  <isVirtual> boolean
  <keys> AccessKeyList
  <returnDecl> ReturnDecl
  <args> List(ArgumentDecl)
  .
MethodName =
  <value> String
  .
MethodBodyVersion =
  <value> String
  .
AccessKey =
  <tag> String
  .
TypeDecl : 
  ReturnDecl | ArgumentDecl
  *common*
    <prefix> String
    <suffix> String
    <isRef> boolean
    <type> TypeUse
    <auxType> List(TypeUse)
  .
ReturnDecl =
  .
ArgumentDecl =
  <name> ArgumentName
  [ Initializer ]
  .
ArgumentName =
  <value> String
  .
Initializer =
  <value> String
  .
TypeUse =
  <typeName> TypeName
  <byValue> boolean
  [<type> DefinedType]
  .
//============================================================
// Program classes
//------------------------------------------------------------
Main = .

//============================================================
// Utilities
//------------------------------------------------------------
List(E) ~ {E}.