Definition of quirk21b.

Quirk21b is a language with the same semantics as quirk21a but
with the following differences in syntax:

    Every <mod> contains a section delimited by { and }.
    Every <vardec> ends with a semicolon.
    Every <fundec> ends with a semicolon.
    The body of a lambda expression is delimited by { and }.
    Formal parameters are declared as in Java.
    Compound statements are written as in Java, not as in Pascal.

****************************************************************

Syntax of quirk21b.  [Revision 0]

Revision history:

****************************************************************

<pgm>            ::=  <exp> where <mods>

<mod>            ::=  export <ids> from { <decs> }
                   |  export <ids> from { <decs> where <exps> }

<dec>            ::=  variables <vardecs>
                   |  functions <fundecs>

<vardec>         ::=  <id> = <exp> ;
<fundec>         ::=  <id> = <function> ;

<type>           ::=  <argtype>
                   |  <newtype>

<argtype>        ::=  <typename>
                   |  <functiontype>

<typename>       ::=  <primtype>  |  <id>

<primtype>       ::=  boolean  |  int

<functiontype>   ::=  ( <argtypes> -> <rtype> )

<rtype>          ::=  void  |  <argtype>

<function>       ::=  lambda ( <formals> ) : <rtype> { <exp> }

<formal>         ::=  <type> <id>

<exp>            ::=  <lhs>
                   |  <function>
                   |  let <vardecs> in <exp>
                   |  if <exp> then <exp> else <exp>
                   |  while <exp> do <exp>
                   |  for <vardec> to <exp> do <exp>
                   |  { <exps> }
<lhs>            ::=  <disjunct>
                   |  <disjunct> <orop> <lhs>
<disjunct>       ::=  <conjunct>
                   |  <conjunct> <andop> <disjunct>
<conjunct>       ::=  <simple>
                   |  <simple> <relop> <simple>
<simple>         ::=  <term>
                   |  <simple> <addop> <term>
<term>           ::=  <factor>
                   |  <term> <mulop> <factor>
<factor>         ::=  <unop> <factor>
                   |  <literal>
                   |  ( <exp> ) <factor-rest>
                   |  <id> <factor-rest>
<factor-rest>    ::=  
                   |  ( <actuals> ) <factor-rest>

<literal>        ::=  true  |  false
                   |  stringliteral
                   |  intliteral


<mods>           ::=  <empty>  |  <mod> <mods>
<ids>            ::=  <id>  |  <id> , <ids>
<decs>           ::=  <dec>  |  <dec> <decs>
<exps>           ::=  <exp>  |  <exp> ; <exps>
<actuals>        ::=  <empty>  |  <exp> <actuals-rest>
<actuals-rest>   ::=  <empty>  |  , <exp> <actuals-rest>
<vardecs>        ::=  <vardec>  |  <vardec> <vardecs>
<fundecs>        ::=  <fundecs>  |  <fundec> <fundecs>
<argtypes>       ::=  <empty>  |  <argtypes1>
<argtypes1>      ::=  <argtype>  |  <argtype> * <argtypes1>
<formals>        ::=  <empty>  |  <formals1>
<formals1>       ::=  <formal>  |  <formal> , <formals1>


<orop>           ::=  or
<andop>          ::=  and
<relop>          ::=  ==  |  !=  |  <  |  <=  |  >  |  >=
<addop>          ::=  +  |  -
<mulop>          ::=  *  |  /
<unop>           ::=  !  |  -

<id>             ::=  id