Definition of the quirk21a subset of quirk21.

Quirk21a is the subset of quirk21 obtained by omitting:

    type declarations
    sum and product types
    char and float types
    array types (other than literals of type char[])
    assignments
    letrec expressions
    new expressions (for both array and sum/product types)
    case expressions
    field references
    array references
    char literals
    float literals
    all operations on char types
    all operations on float types
    all operations on array types

String literals are permitted, but the only thing a program can
do with them is pass them to a library procedure.

The three library procedures are

    printString
    printInt
    printLine

****************************************************************

Syntax of quirk21a.  [Revision 0]

Revision history:

****************************************************************

<pgm>            ::=  <exp> where <mods>

<mod>            ::=  export <ids> from <decs>
                   |  export <ids> from <decs> where <exps>

<dec>            ::=  variables <vardecs>
                   |  functions <fundecs>

<vardec>         ::=  <id> = <exp>
<fundec>         ::=  <id> = <function>

<type>           ::=  <argtype>
                   |  <newtype>

<argtype>        ::=  <typename>
                   |  <functiontype>

<typename>       ::=  <primtype>  |  <id>

<primtype>       ::=  boolean  |  int

<functiontype>   ::=  ( <argtypes> -> <rtype> )

<rtype>          ::=  void  |  <argtype>

<function>       ::=  lambda ( <formals> ) : <rtype> . <exp>

<formal>         ::=  <id> : <type>

<exp>            ::=  <lhs>
                   |  <function>
                   |  let <vardecs> in <exp>
                   |  if <exp> then <exp> else <exp>
                   |  while <exp> do <exp>
                   |  for <vardec> to <exp> do <exp>
                   |  begin <exps> end
<lhs>            ::=  <disjunct>
                   |  <disjunct> <orop> <lhs>
<disjunct>       ::=  <conjunct>
                   |  <conjunct> <andop> <disjunct>
<conjunct>       ::=  <simple>
                   |  <simple> <relop> <simple>
<simple>         ::=  <term>
                   |  <simple> <addop> <term>
<term>           ::=  <factor>
                   |  <term> <mulop> <factor>
<factor>         ::=  <unop> <factor>
                   |  <literal>
                   |  ( <exp> ) <factor-rest>
                   |  <id> <factor-rest>
<factor-rest>    ::=  
                   |  ( <actuals> ) <factor-rest>

<literal>        ::=  true  |  false
                   |  stringliteral
                   |  intliteral


<mods>           ::=  <empty>  |  <mod> <mods>
<ids>            ::=  <id>  |  <id> , <ids>
<decs>           ::=  <dec>  |  <dec> <decs>
<exps>           ::=  <exp>  |  <exp> ; <exps>
<actuals>        ::=  <empty>  |  <exp> <actuals-rest>
<actuals-rest>   ::=  <empty>  |  , <exp> <actuals-rest>
<vardecs>        ::=  <vardec>  |  <vardec> <vardecs>
<fundecs>        ::=  <fundecs>  |  <fundec> <fundecs>
<argtypes>       ::=  <empty>  |  <argtypes1>
<argtypes1>      ::=  <argtype>  |  <argtype> * <argtypes1>
<formals>        ::=  <empty>  |  <formals1>
<formals1>       ::=  <formal>  |  <formal> , <formals1>


<orop>           ::=  or
<andop>          ::=  and
<relop>          ::=  ==  |  !=  |  <  |  <=  |  >  |  >=
<addop>          ::=  +  |  -
<mulop>          ::=  *  |  /
<unop>           ::=  !  |  -

<id>             ::=  id