Syntax of Quirk21.  [Revision 1]

Revision history:

Revision 1, 16 Sept 2004:
    Corrected the production for new array values.

****************************************************************

<pgm>            ::=  <exp> where <mods>

<mod>            ::=  export <ids> from <decs>
                   |  export <ids> from <decs> where <exps>

<dec>            ::=  variables <vardecs>
                   |  functions <fundecs>
                   |  types <typedecs>

<vardec>         ::=  <id> = <exp>
<fundec>         ::=  <id> = <function>
<typedec>        ::=  <id> = <newtype>

<type>           ::=  <argtype>
                   |  <newtype>

<argtype>        ::=  <typename>
                   |  <arraytype>
                   |  <functiontype>

<typename>       ::=  <primtype>  |  <id>

<primtype>       ::=  boolean  |  char  |  int  |  float

<arraytype>      ::=  <argtype> []

<functiontype>   ::=  ( <argtypes> -> <rtype> )

<rtype>          ::=  void  |  <argtype>

<newtype>        ::=  <sumtype>
                   |  <producttype>

<sumtype>        ::=  oneof { <fielddecs> }

<producttype>    ::=  allof { <fielddecs> }

<fielddec>       ::=  <id> : <argtype>

<function>       ::=  lambda ( <formals> ) : <rtype> . <exp>

<formal>         ::=  <id> : <type>

<field>          ::=  <id> : <exp>

<exp>            ::=  <lhs>
                   |  <lhs> <assignop> <exp>
                   |  <function>
                   |  let <vardecs> in <exp>
                   |  letrec <fundecs> in <exp>
                   |  new <argtype> [ <exp> ] <exp>                           !
                   |  new <id> { <fields> }
                   |  case <exp> of <cases> else <exp>
                   |  if <exp> then <exp> else <exp>
                   |  while <exp> do <exp>
                   |  for <vardec> to <exp> do <exp>
                   |  begin <exps> end
<lhs>            ::=  <disjunct>
                   |  <disjunct> <orop> <lhs>
<disjunct>       ::=  <conjunct>
                   |  <conjunct> <andop> <disjunct>
<conjunct>       ::=  <simple>
                   |  <simple> <relop> <simple>
<simple>         ::=  <term>
                   |  <simple> <addop> <term>
<term>           ::=  <factor>
                   |  <term> <mulop> <factor>
<factor>         ::=  <unop> <factor>
                   |  <literal>
                   |  ( <exp> ) <factor-rest>
                   |  <id> <factor-rest>
<factor-rest>    ::=  
                   |  ( <actuals> ) <factor-rest>
                   |  . <id> <factor-rest>
                   |  [ <exp> ] <factor-rest>

<case>           ::=  <id> : <id> then <exp>

<literal>        ::=  true  |  false
                   |  charliteral
                   |  stringliteral
                   |  intliteral
                   |  floatliteral


<mods>           ::=  <empty>  |  <mod> <mods>
<ids>            ::=  <id>  |  <id> , <ids>
<decs>           ::=  <dec>  |  <dec> <decs>
<exps>           ::=  <exp>  |  <exp> ; <exps>
<actuals>        ::=  <empty>  |  <exp> <actuals-rest>
<actuals-rest>   ::=  <empty>  |  , <exp> <actuals-rest>
<vardecs>        ::=  <vardec>  |  <vardec> <vardecs>
<fundecs>        ::=  <fundecs>  |  <fundec> <fundecs>
<typedecs>       ::=  <typedec>  |  <typedec> <typedecs>
<argtypes>       ::=  <empty>  |  <argtypes1>
<argtypes1>      ::=  <argtype>  |  <argtype> * <argtypes1>
<fielddecs>      ::=  <fielddec>  |  <fielddec> , <fielddecs>
<formals>        ::=  <empty>  |  <formals1>
<formals1>       ::=  <formal>  |  <formal> , <formals1>
<fields>         ::=  <field>  |  <field>, <fields>
<cases>          ::=  <case>  |  <case> <cases>


<assignop>       ::=  :=
<orop>           ::=  or
<andop>          ::=  and
<relop>          ::=  ==  |  !=  |  <  |  <=  |  >  |  >=
<addop>          ::=  +  |  -
<mulop>          ::=  *  |  /
<unop>           ::=  !  |  -  |  #

<id>             ::=  id