Syntax of quirk20.  [Revision 1]

<program>        ::=  <classdec>
                   |  <classdec> <program>

<type>           ::=  <primtype>
                   |  <typeid>
                   |  <type> []
                   |  function ( from ( <types> ) to <rtype> )

<primtype>       ::=  boolean
                   |  char
                   |  String
                   |  int
                   |  double

<rtype>          ::=  <type>
                   |  void

<classdec>       ::=  class <typeid> { <bodydecs> }

<bodydec>        ::=  <access> <constdec>
                   |  <access> <globaldec>
                   |  <access> <fielddec>
                   |  <access> <fundec>

<access>         ::=  
                   |  public

<constdec>       ::=  constant <primtype> <id> = <literal> ;

<globaldec>      ::=  static <primtype> <id> = <literal> ;

<fielddec>       ::=  <formal> ;

<formal>         ::=  <type> <id>

<fundec>         ::=  proc <rtype> <id> ( <formals> ) <block>

<block>          ::=  { <localdecs> <stms> }

<localdec>       ::=  <vardec>
                   |  <fundec>

<vardec>         ::=  <type> <id> = <exp> ;

<stm>            ::=  ;
                   |  <exp> ;
                   |  if ( <exp> ) <stm> else <stm>
                   |  when ( <exp> ) <stm>
                   |  unless ( <exp> ) <stm>
                   |  while ( <exp> ) <stm>
                   |  for ( <vardec> <exp> ; <exp> ) <stm>
                   |  return <exp> ;
                   |  <block>

<exp>            ::=  <lhs>
                   |  <lhs> <assignop> <exp>
<lhs>            ::=  <disjunct>
                   |  <disjunct> <orop> <lhs>
<disjunct>       ::=  <conjunct>
                   |  <conjunct> <andop> <disjunct>
<conjunct>       ::=  <simple>
                   |  <simple> <relop> <simple>
<simple>         ::=  <term>
                   |  <simple> <addop> <term>
<term>           ::=  <factor>
                   |  <term> <mulop> <factor>
<factor>         ::=  <unop> <factor>
                   |  <literal>
                   |  new <typeid> ()
                   |  new <type> [ <exp> ]
                   |  ( <exp> ) <factor-rest>
                   |  <id> <factor-rest>
                   |  <typeid> . <id> <factor-rest>
<factor-rest>    ::=  
                   |  ( <actuals> ) <factor-rest>
                   |  . <id> <factor-rest>                        
                   |  [ <exp> ] <factor-rest> 

<literal>        ::=  null  |  true  |  false
                   |  charliteral
                   |  Stringliteral
                   |  intliteral
                   |  floatliteral

<empty>          ::=
<types>          ::=  <empty>  |  <type> <types-rest>
<types-rest>     ::=  <empty>  |  , <type> <types-rest>
<bodydecs>       ::=  <empty>  |  <bodydec> <bodydecs>
<localdecs>      ::=  <empty>  |  <localdec> <localdecs>
<stms>           ::=  <empty>  |  <stm> <stms>
<formals>        ::=  <empty>  |  <formal> <formals-rest>
<formals-rest>   ::=  <empty>  |  , <formal> <formals-rest>
<actuals>        ::=  <empty>  |  <exp> <actuals-rest>                
<actuals-rest>   ::=  <empty>  |  , <exp> <actuals-rest>

<assignop>       ::=  =                                          
<orop>           ::=  ||
<andop>          ::=  &&
<relop>          ::=  ==  |  !=  |  <  |  <=  |  >  |  >=
<addop>          ::=  +  |  -
<mulop>          ::=  *  |  /
<unop>           ::=  !  |  -

<id>             ::=  id                                    
<typeid>         ::=  typeid