include "lib.java.cd";

package scg;

nogen RWrap(T) = <className> FullyQualifiedClassName <wrappee> verbatim.
FullyQualifiedClassName =  <name> ident <rest> DSLOI.
DSLOI = DSCOI | DSEOI.
DSCOI = "." <first> ident <rest> DSLOI.
DSEOI = .

// Domain
interface DomainI = .
interface InstanceI = .
interface SolutionI = .
interface InstanceSetI = .

// Claims
Claim =  <instanceSetWrapper> RWrap(InstanceSetI) <protocolWrapper> RWrap(ProtocolI) <quality> double.

// Protocols
interface ProtocolI = .  

ProtocolSpec = <steps> List(Step).
Step = <action> Action "from" <role> Role .
interface Role = Alice | Bob.
Alice = "Alice".
Bob = "Bob".
interface Action = ProvideAction | SolveAction.
//can only provide for the claim
ProvideAction = "instance". 
//solve the instance provided in step # stepNo
//step # -1 for the singleton instance in claim
// stepNo is 0-based
SolveAction = "solution" "of" <stepNo> int. 



//Requests and Transactions
PlayerRequest = "request[" <request> Request "]".
Request = ProposeRequest | OpposeRequest | ProvideRequest | SolveRequest.

PlayerResponse = "transaction[" <transaction> Response "]".
Response = ProposeResponse | OpposeResponse | ProvideResponse | SolveResponse.

//In a turn, only one proposeRequest and one OpposeRequest are passed to the avatar
ProposeRequest = "propose" <forbidden> List(Claim).
OpposeRequest = "oppose" <claims> List(Claim).
ProvideRequest = "provide" <claim> Claim.
SolveRequest = "solve" <instanceWrapper> RWrap(InstanceI) <claim> Option(Claim).

ProposeResponse = "propose" <claims> List(Claim).
OpposeResponse = "oppose" <oppositions> List(OpposeAction).
OpposeAction = NoOpposition | Strengthening | Refuting.
NoOpposition = "no" "opposition".
Strengthening = "strengthening" <newQuality> double.
Refuting = "refuting".
ProvideResponse = "provide" <instanceWrapper> RWrap(InstanceI).
SolveResponse = "solve" <solutionWrapper> RWrap(SolutionI).


//config common to all games
SCGConfig =
  "scg_config["
            *l*t "tournamentStyle:" *s <tournamentStyle> TournamentStyle

            *l*t "turnDuration:" *s <turnDuration> int
        // number of seconds

            *l*t "maxNumAvatars:" *s <maxNumAvatars> int
        // per tournament

            *l*t "minStrengthening:" *s <minStrengthening> double
        // minimum amount of strengthening by a strengthening oppose

            *l*t "initialReputation:" *s <initialReputation> double
        // initial reputation of an avatar

            *l*t "maxReputation:" *s <maxReputation> double
        // maximum reputation a scholar can reach
        // game ends when reached

            *l*t "reputationFactor:" *s <reputationFactor> double
        // a number in [0,1] used to determine reputation gain
        // upon successful defense of own claim or
        // upon successful refutation of claim of another scholar.

            *l*t "minProposals:" *s <minProposals> int
            *l*t "maxProposals:" *s <maxProposals> int
        // scholars must stay active, but not too active

            *l*t "numRounds:" *s <numRounds> int
        // the number of rounds for a tournament

            *l*t "proposedClaimMustBeNew:" *s <proposedClaimMustBeNew> boolean
        // proposed claims must be different from previously proposed claims

            *l
         "]".

TournamentStyle = FullRoundRobin | KnockOut | SwissStyleTournament.
FullRoundRobin = "full" "round-robin".
KnockOut = "knockout".
SwissStyleTournament = "swiss".

interface DomainConfigI = .       

//config definitions
Config =  <scgCfg> SCGConfig  <domainConfigWrapper> RWrap(DomainConfigI).


//baby avatar definitions
interface AvatarI = .