include "lib.java.cd";

package scg;

import java.lang.reflect.*;

FullyQualifiedClassName = <name> ident <rest> List(Qualifier).
Qualifier = "." <name> ident.


// Domain
interface DomainI = .
interface InstanceI = .
interface SolutionI = .
interface InstanceSetI = .

//Wrappers for instance, solution, instanceSet
Instance = <instanceClassName> FullyQualifiedClassName <instance> InstanceI <instanceSpec> verbatim.
InstanceSet = <instanceSetClassName> FullyQualifiedClassName <instanceSet> InstanceSetI <instanceSetSpec> verbatim.
Solution = <solutionClassName> FullyQualifiedClassName <solution> SolutionI <solutionSpec> verbatim.


// Claims
Claim =  <instanceSet> InstanceSet <protocolClassName> FullyQualifiedClassName <protocol> ProtocolI  <quality> double.
interface ProtocolI = .  


ProtocolSpec = <steps> List(Step).
Step = <action> Action "from" <role> Role .
Role = Alice | Bob.
Alice = "Alice".
Bob = "Bob".
Action = ProvideAction | SolveAction.
//can only provide for the claim
ProvideAction = "instance". 
//solve the instance provided in step # stepNo
//step # -1 for the singleton instance in claim
// stepNo is 0-based
SolveAction = "solution" "of" <stepNo> int. 



//Requests and Transactions
PlayerRequest = "request[" <request> Request "]".
Request = ProposeRequest | OpposeRequest | ProvideRequest | SolveRequest.

PlayerResponse = "transaction[" <transaction> Response "]".
Response = ProposeResponse | OpposeResponse | ProvideResponse | SolveResponse.

//In a turn, only one proposeRequest and one OpposeRequest are passed to the avatar
ProposeRequest = "propose" <forbidden> List(Claim).
OpposeRequest = "oppose" <claims> List(Claim).
ProvideRequest = "provide" <claim> Claim.
SolveRequest = "solve" <instance> Instance <claim> Option(Claim).

ProposeResponse = "propose" <claims> List(Claim).
OpposeResponse = "oppose" <oppositions> List(OpposeAction).
OpposeAction = NoOpposition | Strengthening | Refuting.
NoOpposition = "no" "opposition".
Strengthening = "strengthening" <newQuality> double.
Refuting = "refuting".
ProvideResponse = "provide" <instance> Instance.
SolveResponse = "solve" <instance> Instance.