// by Ahmed Mohsen and Karl Lieberherr
// Nov. 9, 2006
// a relation referenced in a constraint must be referenced by name
// If you support negated literals in the scope of
// a constraint, you get extra credit.
// Note that the outsourcing team expects fractions for relations
// where all variables are not negated.

// semantic checks
// nbValues consistent with tuples
// nbConstraints correct
// nbVariables correct
// all relations must be defined by relation number

Instance = 
     "<" "instance" ">" 
         <presentation> PresentationXMLElement
         [<domains> DomainsXMLElement]
         <variables> VariablesXMLElement
         <relations> RelationsXMLElement
         <constraints> ConstraintsXMLElement
     "<" "/" "instance" ">" EOF.

//presentation XML element
PresentationXMLAttribute: 
	PresentationNameAttribute |
	PresentationMaxConstraintArityAttribute |
	PresentationNbSolutionAttribute |
	PresentationSolutionAttribute |
	PresentationMaxSatisfiableConstraintsAttribute |
	PresentationFormatAttribute.

PresentationNameAttribute = "name" "=" <name> String.
PresentationMaxConstraintArityAttribute = "maxConstraintArity" "=" <maxConstraintArity> String.
PresentationNbSolutionAttribute = "nbSolutions" "=" <nbSolutions> String.
PresentationSolutionAttribute = "solution" "=" <solution> String.
PresentationMaxSatisfiableConstraintsAttribute = "maxSatisfiableConstraints" "=" <maxSatisfiableConstraints> String.
PresentationFormatAttribute = "format" "=" <format> String.

PresentationXMLAttributeList = List(PresentationXMLAttribute).
PresentationXMLElement = "<" "presentation" PresentationXMLAttributeList "/" ">".

//domain XML element
DomainNameAttribute = "name" "=" <name> String.
DomainNbValuesAttribute = "nbValues" "=" <nbValues> String.
DomainExp: Num|Dot.
Num = <v> int.
Dot = "..".
DomainXMLElement = 
	"domain" [DomainNameAttribute] DomainNbValuesAttribute ">" 
	List(DomainExp)
	"<" "/" "domain" ">"
	"<".

//domains XML element
DomainsNbDomainsAttribute = "nbDomains" "=" <nbDomains> String.
DomainsXMLElement = 
	/// !! change
	"<domains" DomainsNbDomainsAttribute ">" 
	"<"
	List(DomainXMLElement)
	"/" "domains" ">".
	
//variable XML element
variableNameAttribute = "name" "=" <name> String.
variableDomainAttribute = "domain" "=" <domain> String.
VariableXMLElement = 
	"variable" 
	variableNameAttribute
	variableDomainAttribute  
	"/" ">" 
	"<".


VariablesNbVariablesAttribute = "nbVariables" "=" <nbVariables> String.
VariablesXMLElement = 
	"<" "variables" VariablesNbVariablesAttribute">"
	"<"
	List(VariableXMLElement)
	"/" "variables" ">".

//relation XML element
RelationNameAttribute = "name" "=" <name> String.
RelationNumberAttribute = "number" "=" <number> String.
RelationArityAttribute = "arity" "=" <arity> String.
RelationNbTuplesAttribute = "nbTuples" "=" <nbTuples> String.
RelationSemanticsAttribute = "semantics" "=" <semantics> String.

RelationXMLElement = 
	"relation" 
	RelationNameAttribute 
	RelationNumberAttribute 
	[RelationArityAttribute] [RelationNbTuplesAttribute] [RelationSemanticsAttribute] ">" 
	[ <tuples> PipeList(Tuple)]
	"<" "/" "relation" ">"
	"<".

Tuple = NList(Digit).
Digit = <v> int.

//Relations XML element
RelationsNbRelationsAttribute = "nbRelations" "=" <nbRelations> String.
RelationsXMLElement = 
	"<" "relations" RelationsNbRelationsAttribute ">" 
	"<"
	List(RelationXMLElement)
	"/" "relations" ">".

//Constraint XML element
ConstraintNameAttribute = "name" "=" <name> String.
ConstraintArityAttribute = "arity" "=" <arity> String.
ConstraintXMLAttributes = 
      [ConstraintNameAttribute] 
      [ConstraintArityAttribute] 
      ScopeAttribute 
      ReferencesAttribute. 
ScopeAttribute = "scope" "=" <scope> String.
ReferencesAttribute = "reference" "=" <references> String.
ConstraintXMLElement = "constraint" ConstraintXMLAttributes "/" ">" "<".

//constraints XML element
ConstraintsXMLAttributes = "nbConstraints" "=" <nbConstraints> String.
ConstraintsXMLElement = 
	"<" "constraints" ConstraintsXMLAttributes ">"
	"<"
	List(ConstraintXMLElement)
	"/" "constraints" ">".

//Other stuff
List(S) ~ {S}.
NList(S) ~ S{S}.
PipeList(S) ~ S {"|" S}.
Main = .