// semcheck.cd
//
// This file defines the class dictionary for the
// XAspects language.

import edu.neu.ccs.demeter.dj.*;
import edu.neu.ccs.demeter.aplib.*;
import java.util.*;

AspectFile = <cdAspect> ClassDictionaryAspect <tAspect> TraversalAspect.
ClassDictionaryAspect = "aspect" "(ClassDictionary)" <name> AspectName <textcd> TextCD.
TraversalAspect = "aspect" "(Traversal)" <name> AspectName "{" List(Declaration) "}".

// traversal aspect declarations
Declaration = "declare" GeneralDeclaration.
GeneralDeclaration : StrategyDecl | NodesetDecl.
StrategyDecl = "strategy" ":" <name> StrategyDeclName ":" StrategyExpression ";".
NodesetDecl = "node" "set" ":" <name> NodesetDeclName ":" NodesetDef ";".

// definition of strategy
StrategyExpression	= Strategy.
public Strategy		: SimpleStrategy | StrategyCombination
			| StrategyReference.

public SimpleStrategy	: StrategyGraph | PathDirective
			common [ "with" *s <parsedNameMap> NameMap ].
public StrategyGraph	= "{" *l + <edges> SList(SGEdge) - *l "}".

SGEdge			= [ SourceMarker *s ] <source> GlobSpec *s "->" *s
			  [ TargetMarker *s ] <target> GlobSpec
			  [ *s <constraint> NegativeConstraint ].

SourceMarker		= "source:".
TargetMarker		= "target:".

public PathDirective	= <source> SourceDirective
			  [ *s <constraint> NegativeConstraint ]
			  <segments> List(PathSegment)
			  *s <target> TargetDirective.

SourceDirective		: From common *s <sources> ClassGlobSpec.
From			= "from".

PathSegment		= <node> PositiveConstraint
			  [ *s <constraint> NegativeConstraint ].

Constraint		: PositiveConstraint | NegativeConstraint
			common *s <glob> GlobSpec.
PositiveConstraint	: Through | Via.		// synonyms
Through			= "through".
Via			= "via".
NegativeConstraint	: Bypassing | OnlyThrough.	// antonyms
Bypassing		= "bypassing".
OnlyThrough		= "only-through".

TargetDirective		: To | ToStop common *s <targets> ClassGlobSpec.
To			= "to".
ToStop			= "to-stop".

public StrategyCombination
			: Join | Merge | Intersect
			  common "(" <first> Strategy "," *s
				     <rest> Commalist(Strategy) ")".

Join			= "join".
Merge			= "merge".
Intersect		= "intersect".

public StrategyReference
			= Ident.

SymbolicNameMap		: NameMap. // implements SymbolicNameMapI.
NameMap			= "{" *s [ <bindings> Commalist(NameBinding) *s ] "}".
NameBinding		= <sgName> Name "=" <cgNames> ClassGlobSpec.

GlobSpec		: OneGlob | GlobSet.
OneGlob			= Glob.
GlobSet			= "{" *s [ <globs> Commalist(Glob) *s ] "}".

Glob			: ClassGlob | EdgeGlob.
EdgeGlob		: PartGlob | SubclassGlob | SuperclassGlob.

ClassGlob		= <name> ClassNameGlob.
PartGlob		= "->" *s <source> SourceGlob ","
				  <name> PartNameGlob ","
			          <target> TargetGlob.
SubclassGlob		= "=>" *s <source> SourceGlob "," <target> TargetGlob.
SuperclassGlob		= ":>" *s <source> SourceGlob "," <target> TargetGlob.

SourceGlob		= <name> ClassNameGlob.
TargetGlob		= <name> ClassNameGlob.

ClassNameGlob		: ClassNameExact | AnyClass.
ClassNameExact		= ClassName.
AnyClass		= "*".

PartNameGlob		: PartNameExact | AnyPart.
PartNameExact		= PartName.
AnyPart			= "*".

ClassGlobSpec		: OneClassGlob | ClassGlobSet.
OneClassGlob		= ClassGlob.
ClassGlobSet		= "{" *s <globs> Commalist(ClassGlob) *s "}".

ClassName		= Name.
PartName		= <name> Ident.
Name			~ Ident { "." Ident }.

// Parameterized class definitions.
List(S) ~ {*s S}.
SList(S) ~ S { *l S } .
Commalist(S) ~ S {"," *s S}.

// definition of nodeset
NodesetDef : NodesDef | ClassListDef | RegularExpression.
NodesDef  = "nodes" <name> StrategyName.
ClassListDef = CList(ClassListName).
// definition of regular expression
RegularExpression = ComplexExp.
RegExp : SimpleExp | ComplexExp.
SimpleExp = NodesetIdent.
ComplexExp : AndExp | OrExp.
AndExp = "and" <args> ExpArguments.
OrExp = "or" <args> ExpArguments.
ExpArguments = "(" <l> RegExp "," <r> RegExp ")".
NodesetIdent = [Complement] Ident.
Complement = "!".

// terminal buffer classes
AspectName = Ident.
TextCD = Text.
StrategyDeclName = Ident.
NodesetDeclName = Ident.
StrategyName = Ident.
ClassListName = Ident.

List (S) ~ {S}.
CList(S) ~ S {"," S}.

Main = .
SemanticChecker = .