// sg.cd -- class dictionary for strategy graphs
// $Id: sg.cd,v 1.12 2003/01/30 02:26:05 dougo Exp $

//Josh Breckman and Rob Thomas

//package edu.neu.ccs.demeter.aplib.sg.project;

import java.util.*;
import java.io.*;
import edu.neu.ccs.demeter.aplib.*;
import edu.neu.ccs.demeter.aplib.cd.*;

Main = . // testing stub

StrategyExpression = Strategy.

public Strategy  : SimpleStrategy | StrategyCombination | StrategyReference implements StrategyI.
public SimpleStrategy : StrategyGraph | PathDirective common [ "with" *s <parsedNameMap> NameMap ].
public StrategyGraph = "{" *l + <edges> SList(SGEdge) - *l "}" implements SimpleStrategyI, StrategyGraphI, ConstraintMapI.

SGEdge = [ SourceMarker *s ] <source> GlobSpec *s "->" *s
     [ TargetMarker *s ] <target> GlobSpec
     [ *s <constraint> NegativeConstraint ]
     implements Cloneable.
SourceMarker = "source:".
TargetMarker = "target:".

public PathDirective = <source> SourceDirective
     [ *s <constraint> NegativeConstraint ]
     <segments> List(PathSegment)
     *s <target> TargetDirective.

SourceDirective  : From common *s <sources> ClassGlobSpec.
From = "from".

PathSegment = <node> PositiveConstraint [ *s <constraint> NegativeConstraint ].

Constraint : PositiveConstraint | NegativeConstraint common *s <glob> GlobSpec.
PositiveConstraint : Through | Via.    // synonyms
Through = "through".
Via = "via".
NegativeConstraint : Bypassing | OnlyThrough.  // antonyms
Bypassing = "bypassing".
OnlyThrough = "only-through".

TargetDirective : To | ToStop common *s <targets> ClassGlobSpec.
To = "to".
ToStop = "to-stop".

public StrategyCombination : Join | Merge | Intersect
        common "(" <first> Strategy "," *s
        <rest> Commalist(Strategy) ")"
        implements StrategyCombinationI, Cloneable.
Join = "join".
Merge = "merge".
Intersect = "intersect".

public StrategyReference = Ident.

SymbolicNameMap : NameMap implements SymbolicNameMapI.
NameMap = "{" *s [ <bindings> Commalist(NameBinding) *s ] "}".
NameBinding = <sgName> Name "=" <cgNames> ClassGlobSpec.

GlobSpec : OneGlob | GlobSet.
OneGlob = Glob.
GlobSet = "{" *s [ <globs> Commalist(Glob) *s ] "}".

Glob : ClassGlob | EdgeGlob.
EdgeGlob : PartGlob | SubclassGlob | SuperclassGlob.

ClassGlob = <name> ClassNameGlob.
PartGlob = "->" *s <source> SourceGlob "," <name> PartNameGlob "," <target> TargetGlob.
SubclassGlob = "=>" *s <source> SourceGlob "," <target> TargetGlob.
SuperclassGlob = ":>" *s <source> SourceGlob "," <target> TargetGlob.

SourceGlob = <name> ClassNameGlob.
TargetGlob = <name> ClassNameGlob.

ClassNameGlob : ClassNameExact | AnyClass.
ClassNameExact = ClassName.
AnyClass    = "*".

PartNameGlob    : PartNameExact | AnyPart.
PartNameExact    = PartName.
AnyPart      = "*".

ClassGlobSpec    : OneClassGlob | ClassGlobSet.
OneClassGlob    = ClassGlob.
ClassGlobSet    = "{" *s <globs> Commalist(ClassGlob) *s "}".

ClassName    = Name.
PartName    = <name> Ident.
Name      ~ Ident { "." Ident }.

// Parameterized class definitions.
List(S) ~ {*s S}.
SList(S) ~ S { *l S } .
Commalist(S) ~ S {"," *s S}.

//XAspect Stuff

XAspect =  <cd> XAspectCD <trav> XAspectTraversals. 

XAspectCD = "aspect" "(" "ClassDictionary" ")" <cdName> Ident <cdText> Text.

XAspectTraversals = "aspect" "(" "Traversal" ")" <travName> Ident "{" <strategies> List(AspectStrategy) <nodes> List(AspectNodeSet) "}".

AspectStrategy = "declare strategy: " <strategyName> Ident ":" <strategy> Strategy ";".

AspectNodeSet = "declare node set: " <nodesetName> Ident ":" <node> Node.

Node : Nodes | NodeRegExp | NodeExp | NodeList.

Nodes = "nodes " <strategyName> Ident ";".

NodeList = Commalist(NodeClassName) ";".

NodeClassName = Ident.

NodeRegExp = "regexp" <regExp> Ident "*" ";".

NodeExp : NodeExpOr | NodeExpAnd | NodeExpNot.
NodeExpL2 : NodeExpOrL2 | NodeExpAndL2 | NodeExpNotL2 | NodeExpIdentL2.

NodeExpOr = "or" "(" <p1> NodeExpL2 "," <p2> NodeExpL2 ")" ";".
NodeExpAnd = "and" "(" <p1> NodeExpL2 "," <p2> NodeExpL2 ")" ";".
NodeExpNot = "!" <p1> NodeExpL2 ";".
NodeExpOrL2 = "or" "(" <p1> NodeExpL2 "," <p2> NodeExpL2 ")".
NodeExpAndL2 = "and" "(" <p1> NodeExpL2 "," <p2> NodeExpL2 ")".
NodeExpNotL2 = "!" <p1> NodeExpL2.
NodeExpIdentL2 = <nodeSetName> Ident.


noparse
interface SymbolicNameMapI = extends NameMapI.
visitors
GlobVisitor    : .