// demjava.cd -- class dictionary for Demeter/Java

(@
  import java.util.*;
  import java.io.*;
@)

Main = .


Program			= [ <pkg> Package ] [ <preamble> JavaCode ] ClassGraph.

Package			~ "package" DirName { "." DirName } ";".

ClassGraph		= <classes> DList(ClassDef).

ClassDef		= ParamClassName ClassParts "."
 			  .

ParamClassName		= ClassName ["(" <parameters> Commalist(ClassName) ")"].

ClassParts		: ConstOrAltClass | RepetitionClass.

ConstOrAltClass		: ConstructionClass | AlternationClass
			*common* + + +
				<parts> List(PartOrSyntax)
				<parents> ClassParents
				 - - -.

PartOrSyntax		: Part | OptionalPart | Syntax.

Part			= [ "<" PartName ">" ] ClassSpec.

OptionalPart		= "[" <part> Sandwich(Part) "]".

ClassParents		= [ "*extends*" <parents> ClassSpec ]
			  [ "*implements*" <interfaces> Commalist(ClassSpec) ] .

ConstructionClass	= "=".

AlternationClass	= ":" + + + <subclasses> Barlist(Subclass) - - -
			[ Common ].

Subclass		= ClassSpec.

Common			= *l + + + "*" "common" "*" - - -.

RepetitionClass		= "~" <sandwiched> Sandwich(RepeatedPart).

RepeatedPart		= [ <nonempty> ClassSpec ]
			"{" <repeated> Sandwich(ClassSpec) "}".

Sandwich(S)		= <first> List(Syntax) <inner> S <second> List(Syntax) .

ClassSpec		= ClassName
			["(" <actual_parameters> Commalist(ClassSpec) ")" ] .


Syntax                  : PlainSyntax | PrintCommand.

PlainSyntax             = <string> String.

PrintCommand            : PrintIndent | PrintUnindent | PrintSkip | PrintSpace.

PrintIndent             = "+" .

PrintUnindent           = "-" .

PrintSkip               = "*l" .

PrintSpace              = "*s" .


// Terminal buffer classes.
DirName			= <name> Ident.
ClassName               = <name> Ident.
PartName                = <name> Ident.
TraversalName           = <name> Ident.
VisitorName             = <name> Ident.
MethodName              = <name> Ident.
JavaCode                = "(@" <code> String "@)".

// Parameterized class definitions.
List(S) ~ {S}.
SList(S) ~ S { *l S } *l .
DList(S) ~ S { *l *l S } *l .
Commalist(S) ~ S {"," S}.
Barlist(S) ~ S { *l "|" S}.

// Extra utility parameterized classes.
Parameterized           = Commalist(Part).
SyntaxTable             = List(PlainSyntax).

// Visitors

// vector of cd defined class names
LeftSide_ClassVisitor   = <left_side> NameContainer.
RightSide_ClassVisitor  = <right_side> NameContainer. 

NameContainer           = *extends* Vector. // Vector(String)