import java.util.*;
import java.io.*;
import edu.neu.ccs.demeter.dj.*;
//******************************************************************************
// Basic definitions
//******************************************************************************
Main		= .
List(S)		~ { + *l S -}.
//******************************************************************************
// PART 1:  Definitions of structures implementing the components of the input
// XML schema specification
//******************************************************************************

Schema		= "<" [ <prefixS> NSRef ] "schema"
		    <attrs> List(AttrValue)
		    ">"
		    <items> List(SchemaItem)
		    "</" [ <prefixE> NSRef ] "schema>" *EOF*.
NSRef		= <namespace> Ident ":".
AttrValue	= [ lookahead (@2@) <prefix> NSRef ]
		    <attrName> Ident "=" <attrValue> String.

SchemaItem	: 
		  lookahead (@4@) Annotation |
		  lookahead (@4@) Attribute |
		  lookahead (@4@) ElementItem |
		  lookahead (@4@) TypeDef 
		  | Comment
		  .

Annotation	= "<" [ <prefixS> NSRef ] "annotation>"
		    List(AnnotationContent)
		    "</" [ <prefixE> NSRef ] "annotation>".
AnnotationContent : 
		    lookahead (@4@) Appinfo |
		    lookahead (@4@) Documentation.
Appinfo		= "<" [ <prefixS> NSRef ] "appinfo>"
		    <attrs> List(AttrValue)
		    "</" [ <prefixE> NSRef ] "appinfo>".
Documentation	= "<" [ <prefixS> NSRef ] "documentation"
		    <attrs> List(AttrValue)
		    RestOfDocumentation.
RestOfDocumentation : EmptyDocumentation | NonEmptyDocumentation.
EmptyDocumentation = "/>".
NonEmptyDocumentation = ">"
			  [ <documentation> String ]
			  "</" [ <prefixE> NSRef ] "documentation>".
Attribute	= "<" [ <prefixS> NSRef ] "attribute"
		    <attrs> List(AttrValue)
		    RestOfAttribute.
RestOfAttribute	: EmptyAttribute | NonEmptyAttribute.
EmptyAttribute	= "/>".
NonEmptyAttribute = ">"
		      [ lookahead (@4@) Annotation ]
		      "</" [ <prefixE> NSRef ] "attribute>".

Element		= "<" [ <prefixS> NSRef ] "element"
		    <attrs> List(AttrValue)
		    RestOfElement.
RestOfElement	: EmptyElement | NonEmptyElement.
EmptyElement	= "/>".
NonEmptyElement	= ">"
		    [ lookahead (@4@) Annotation ]
		    [ lookahead (@4@) <type> TypeDef ]
		    "</" [ <prefixE> NSRef ] "element>".

TypeDef		: lookahead (@4@) SimpleType |
		  lookahead (@4@) ComplexType.
SimpleType	= "<" [ <prefixS> NSRef ] "simpleType"
		    <attrs> List(AttrValue)
		    ">"
		    [ lookahead (@4@) Annotation ]
		    "</" [ <prefixE> NSRef ] "simpleType>".

ComplexType	= "<" [ <prefixS> NSRef ] "complexType"
		    <attrs> List(AttrValue)
		    ">"
		    [ lookahead (@4@) Annotation ]
		    ComplexTypeContent
		    List(Attribute)
		    "</" [ <prefixE> NSRef ] "complexType>".
ComplexTypeContent = 
		     [ lookahead (@4@) ElementItem ].

ElementItem	: 
		  lookahead (@4@) Element |
		  lookahead (@4@) SequenceGroup 
		  .

SequenceGroup	= "<" [ <prefixS> NSRef ] "sequence"
		    <attrs> List(AttrValue)
		    ">"
		    [ lookahead (@4@) Annotation ]
		    List(ElementItem)
		    "</" [ <prefixE> NSRef ] "sequence>".

Comment		= "<!--" <comment> String "-->".